Sheridan Interactive Multimedia - Video Branching in Flash CS3 ActionScript 3

Branching VIDEO code in Flash 9

package interactivevideo {
	
	import flash.display.MovieClip;
	import flash.events.*
	import fl.video.FLVPlayback;
	import fl.video.VideoEvent;
	import flash.filters.BlurFilter;
	
	public class Branching extends MovieClip {
		
		private var myVid:FLVPlayback;
		private var whichVid:Number = 0;
		
		public function Branching() {			
			
			// load four movies into one player
			// load each one as the other one completes
			// once they are all there play the first one
			// when regions are rolled over show and play the right video
			
			// need to put an FLVPlayback component in your library (not on stage)
			myVid = new FLVPlayback();
			myVid.load("start.flv");
			addChildAt(myVid,0);
			
			left.buttonMode = center.buttonMode = right.buttonMode = true;
			left.alpha = center.alpha = right.alpha = 0;					 
						
			// handle loading of the next three videos
			myVid.addEventListener(VideoEvent.READY, readyHandler);
			
			// when finished sets up loops
			myVid.addEventListener(VideoEvent.COMPLETE, completeHandler);
			
			// handle rollovers on clips on the stage and set whichVid should play next
			left.addEventListener(MouseEvent.MOUSE_OVER, function() {whichVid = 1;});
			center.addEventListener(MouseEvent.MOUSE_OVER, function() {whichVid = 2;});
			right.addEventListener(MouseEvent.MOUSE_OVER, function() {whichVid = 3;});								
					
		}
		
		private function readyHandler(e:VideoEvent) {			
			var vid = e.target;
			if (vid.source == "start.flv") {
				vid.activeVideoPlayerIndex = 1;
				vid.load("left.flv");
			} else if (vid.source == "left.flv") {
				vid.activeVideoPlayerIndex = 2;
				vid.load("center.flv");
			} else if (vid.source == "center.flv") {
				vid.activeVideoPlayerIndex = 3;
				vid.load("right.flv");
			} else if (vid.source == "right.flv") {
				vid.activeVideoPlayerIndex = 0;		
				vid.play();		
			}	
		}		
		
		private function completeHandler(e:VideoEvent) {
			var vid = e.target;
			if (vid.visibleVideoPlayerIndex != 0) {
				whichVid = 0;
			}
			vid.activeVideoPlayerIndex = whichVid;
			vid.play();	
			vid.visibleVideoPlayerIndex  = whichVid;
		}
				
	}
}

Here is the ZIP file. Roll over one of the cups. This example was done quickly and for demonstration only, so please excuse the jumps. Please visit our exciting Blog at http://interactivemultimedia.wordpress.com