Sheridan Interactive Multimedia - Video Affecting Blur in Flash CS3 ActionScript 3

Affecting VIDEO code in Flash 9

package interactivevideo {
	
	import flash.display.Sprite;
	import flash.events.*
	import fl.video.FLVPlayback;
	import fl.video.VideoEvent;
	import flash.filters.BlurFilter;
	
	public class Affecting extends Sprite {
		
		private var myVid:FLVPlayback;
		private var filtersArray:Array = [];
		private var videoCenter:Number;
		
		public function Affecting() {
			
			// need to put an FLVPlayback component in your library (not on stage)
			myVid = new FLVPlayback();
			myVid.source = "focus.flv";
			addChild(myVid);						
			
			// when it is ready we get its width and set the initial focus
			myVid.addEventListener(VideoEvent.READY, readyHandler);	
			
			// when finished sets up loop
			myVid.addEventListener(VideoEvent.COMPLETE, completeHandler);		
								
					
		}
		
		private function readyHandler(e:VideoEvent) {			
			videoCenter = myVid.width / 2;	
			adjustFocus();
			this.addEventListener(MouseEvent.MOUSE_MOVE, mouseHandler);		
		}
		
		private function completeHandler(e:VideoEvent) {			
			e.target.seek(0); 
			e.target.play();			
		}
		
		private function mouseHandler(e:MouseEvent) {			
			adjustFocus();
		}		
		
		private function adjustFocus() {				
			var distance =  Math.abs(mouseX - videoCenter)/2;
			var quality = 2;
			myVid.filters = [new BlurFilter(distance, distance, quality)];			
		}
			
		
	}
}

Here is the ZIP file. Roll your cursor over the video. This example was done quickly and for demonstration only. Please visit our exciting Blog at http://interactivemultimedia.wordpress.com